Extending Gold Role Centres with new elements

Adding new elements such as actions, cues, and parts to role centres requires you to create your own AL extension/app (see Development in AL). Below are the standard pages and cue tables we have extended in Gold Role Centres, you can add your own elements by extending these objects.

	Profile ID	Profile Name	Role Centre Page	Activities Page	Cue Table	Headline Page ID
1	ADMIN	Administration	Administrator Main Role Center (8900)	IT Operations Activities (9072)	Administration Cue (9059)	Headline RC Administrator (1445)
2	FIN	Finance	Finance Manager Role Center (8901)	Accountant Activities (9037)	Finance Cue (9054)	Headline RC Accountant (1442)
3	MANUFACTURING	Manufacturing	Manufacturing Manager RC (8903)	Production Planner Activities (9038)	Manufacturing Cue (9056)	Headline RC Prod. Planner (1447)
4	PROJECTS	Project	Project Manager Role Center (8904)	Project Manager Activities (9068)	Job Cue (9057)	Headline RC Project Manager (1443)
5	PURCH	Purchasing	Purchasing Manager Role Center (8905)	Purchase Agent Activities (9063)	Purchase Cue (9055)	FSG_GRC_ HeadlineRCPurchaseMgr (16041512)
6	RESOURCING	Resource	Resource Manager Role Center (8906)	Resource Manager Activities (9067)	Job Cue (9057)	FSG_GRC_ HeadlineRCResourceMgr (16041851)
7	SALES	Sales And Marketing	Sales & Marketing Manager RC (8907)	SO Processor Activities (9060)	Sales Cue (9053)	Headline RC Order Processor (1441)
				Sales & Relationship Mgr. Act. (9076)	Relationship Mgmt. Cue (9063)	Headline RC Relationship Mgt. (1444)
8	SERVICES	Service	Service Manager Role Center (8908)	Service Dispatcher Activities (9057)	Service Cue (9052)	Headline RC Serv. Dispatcher (1448)
9	WAREHOUSE	Warehouse	Warehouse Manager Role Center (8909)	Whse Ship & Receive Activities (9050)	Warehouse Basic Cue (9050)	Headline RC Whse. Basic (1455)
				WMS Ship & Receive Activities (9053)	Warehouse WMS Cue (9051)	Headline RC Whse. WMS (1456)
				Warehouse Worker Activities (9056)	Warehouse Worker WMS Cue (9058)	Headline RC Whse. Worker WMS (1457)

Sample Extensions

The following are some examples of how to extend various parts of the role centres:

Add a custom parts to the role centre

pageextension 50000 SalesAndMarketingRC extends "Sales & Marketing Manager RC"
{
    layout
    {
        addlast(rolecenter)
        {
            part(MyCustomListPart; MyCustomListPart)
            {
                ApplicationArea = All;
            }
        }
    }
}

Add a custom cue to the activities part

tableextension 50000 SalesCue extends "Sales Cue"
{
    fields
    {
        field(50000; MySalesCue; Integer)
        {
            Caption = 'My Sales Cue';
        }
    }
}

pageextension 50001 SOProcessorActivities extends "SO Processor Activities"
{
    layout
    {
        addlast(Content)
        {
            cuegroup(MyCustomCueGroup)
            {
                Caption = 'My Cue Group';

                field(MySalesCue; MySalesCue)
                {
                    ApplicationArea = All;
                    
                    trigger OnDrillDown()
                    begin
                        OpenMySalesPage();
                    end;
                }
            }
        }
    }
}

Add actions to the sections, embedding, and processing areas

pageextension 50000 SalesAndMarketingRC extends "Sales & Marketing Manager RC"
{
    actions
    {
        addlast(Sections)
        {
            group(MySalesGroup)
            {
                action(CustomerList)
                {
                    ApplicationArea = All;
                    Caption = 'Customers';
                    Image = CustomerList;
                    RunObject = Page "Customer List";
                }
            }
        }
        addlast(embedding)
        {
            action(Contacts)
            {
                ApplicationArea = All;
                Caption = 'Contacts';
                Image = CustomerContact;
                RunObject = Page "Contact List";
            }
        }
        addlast(Processing)
        {
            action(SalesPrices)
            {
                ApplicationArea = All;
                Caption = 'Sales Prices';
                Image = SalesPrices;
                RunObject = Page "Sales Prices";
            }
        }
    }
}

Add custom slides to the headline

pageextension 50000 SalesAndMarketingRC extends "Headline RC Order Processor"
{
    layout
    {
        addlast(content)
        {
            group(MyCustomSlide)
            {
                ShowCaption = false;

                field(MyHeadline; MyHeadlineValue)
                {
                    ApplicationArea = All;
                    Caption = 'My Custom Headline';
                    Editable = false;
                }
            }
        }
    }

    var
        MyHeadlineValue: Text;

    trigger OnOpenPage()
    begin
        MyHeadlineValue := CalculateMyHeadlineValue();
    end;
}